BEGIN ~TCWGCIV3~ 2

IF WEIGHT #4 ~RandomNum(5,1)~ THEN BEGIN 0
  SAY ~Things have been very confusing here since we began administering the free cities of the Dragon Coast, as well.  There are so many problems and it takes so long to communicate!  It's awful!~
  IF ~~ THEN EXIT
END

IF WEIGHT #5 ~RandomNum(5,2)~ THEN BEGIN 1
  SAY ~I've just been enumerating the tax landholds in the free cities... and a messanger just arrived from Starmantle telling me that three villages have been burned to the ground by a dragon!  All that work, gone!~
  IF ~~ THEN EXIT
END

IF WEIGHT #6 ~RandomNum(5,3)~ THEN BEGIN 2
  SAY ~If you want anything done, you're going to have to speak to the Council.  And that, of course, is not easy.~
  IF ~~ THEN EXIT
END

IF WEIGHT #7 ~RandomNum(5,4)~ THEN BEGIN 3
  SAY ~(sigh)  If you want to make a request, you'll have to go to the clerk and get the forms.  Fill them out now, so I can get on to ignoring them as quickly as possible.~
  IF ~~ THEN EXIT
END

IF WEIGHT #8 ~RandomNum(5,5)~ THEN BEGIN 4
  SAY ~I just found out we have three man-hunts out for tax evaders who we weren't informed had died over ten years ago.  Hmm.  Maybe if we pretend we still don't know that, we can force someone to pay...~
  IF ~~ THEN EXIT
END

IF WEIGHT #0 ~Detect("TCERIN") !StateCheck("TCERIN",CD_STATE_NOTVALID) RandomNum(2,1) Global("civil02Erin","LOCALS",0)~ THEN BEGIN 5
  SAY ~Er... you look like a bard.  All bards must pay a music fee of 100 gold.~
  IF ~~ THEN DO ~SetGlobal("civil02Erin","LOCALS",1)~ EXTERN ~TCERINJ~ Erin2CivilServant
END

IF WEIGHT #1 ~Detect("TCPARA") !StateCheck("TCPARA",CD_STATE_NOTVALID) RandomNum(2,1) Global("civil02Paraway","LOCALS",0)~ THEN BEGIN 6
  SAY ~I'm sorry, sir... we don't allow elves in these buildings.~
  IF ~~ THEN DO ~SetGlobal("civil02Paraway","LOCALS",1)~ EXTERN ~TCPARAJ~ Paraway2CivilServant
END

IF WEIGHT #2 ~Detect("TCICAR") !StateCheck("TCICAR",CD_STATE_NOTVALID) RandomNum(2,1) Global("civil02Icar","LOCALS",0)~ THEN BEGIN 7
  SAY ~Oooh... wait one moment, you're Captain Icar, aren't you?  You wouldn't happen to know a Markessa Demuir, would you?  As far as we can tell, she hasn't paid taxes in over seven years.~
  IF ~~ THEN DO ~SetGlobal("civil02Icar","LOCALS",1)~ EXTERN ~TCICARJ~ Icar2CivilServant
END

IF WEIGHT #3 ~Detect("TCGROZ") !StateCheck("TCGROZ",CD_STATE_NOTVALID) RandomNum(2,2) Global("civil02Grozhar","LOCALS",0)~ THEN BEGIN 8
  SAY ~Wait... that's an orc, isn't it?  According to article 1201... all orcs must pay a daily fee to remain in the city.~
  IF ~~ THEN DO ~SetGlobal("civil02Grozhar","LOCALS",1)~ EXTERN ~TCGROZJ~ Grozhar2CivilServant
END

IF ~~ THEN BEGIN CSMarkessa
  SAY ~Dead?  She didn't pay her taxes.  She isn't allowed to die without paying her taxes.  Oh, this will take even more paperwork...~
  IF ~~ THEN EXIT
END


APPEND ~TCERINJ~

IF ~~ THEN BEGIN Erin2CivilServant
  SAY ~I, ah, believe that was paid last week.  Yes, you should have the documents in that pile over there. (That should keep him busy for a week.)~
  IF ~~ THEN EXIT
END
END

APPEND ~TCGROZJ~

IF ~~ THEN BEGIN Grozhar2CivilServant
  SAY ~Sure, let me pay with a piece of your flesh.  Get away from me.  Now!~
  IF ~~ THEN EXIT
END
END

APPEND ~TCICARJ~

IF ~~ THEN BEGIN Icar2CivilServant
  SAY ~*Frowning*  Lady Demuir is dead.~
  IF ~~ THEN EXTERN ~TCWGCIV3~ CSMarkessa
END
END

APPEND ~TCPARAJ~

IF ~~ THEN BEGIN Paraway2CivilServant
  SAY ~That is okay, I'm leaving anyway.  Too much hot air in this place.~
  IF ~~ THEN EXIT
END
END
