BEGIN ~TCWGWOM4~ 2

IF WEIGHT #2 ~RandomNum(4,1)~ THEN BEGIN 0
  SAY ~This be the city of thieves, it is.  And even more so in this part o' town.~
  IF ~~ THEN EXIT
END

IF WEIGHT #3 ~RandomNum(4,2)~ THEN BEGIN 1
  SAY ~I expect we'll be seein' more rain, soon.  The weather has been plain awful, as o' late.~
  IF ~~ THEN EXIT
END

IF WEIGHT #4 ~RandomNum(4,3)~ THEN BEGIN 2
  SAY ~You hear what Victor Dhostar had done?  He was the Faceless one he was.  It's a good thing his son stopped him.~
  IF ~~ THEN EXIT
END

IF WEIGHT #5 ~RandomNum(4,4)~ THEN BEGIN 3
  SAY ~You want t' see the head o' the Docks, you speaks to the Captain Girana.  He rules the Night Masks, he does... and the Docks.  Ye'll see none o' the guards, here.~
  IF ~!Dead("TCSLGIR")~ THEN REPLY ~I've met him before.~ EXIT
  IF ~Dead("TCSLGIR")~ THEN REPLY ~Not anymore, I killed him.~ EXIT
END

IF WEIGHT #0 ~Detect("TCRIL") InParty("TCRIL") !StateCheck("TCRIL",CD_STATE_NOTVALID) RandomNum(2,1) Global("TCWGWOM42Ril","TC1000",0)~ THEN BEGIN 4
  SAY ~The weather has been so terrible... I expect the gods have been frownin' on us, they have.~
  IF ~~ THEN DO ~SetGlobal("TCWGWOM42Ril","TC1000",1)~ EXTERN ~TCRILJ~ Ril2WestWoman
END

IF WEIGHT #1 ~Detect("TCRIHN") InParty("TCRIHN") !StateCheck("TCRIHN",CD_STATE_NOTVALID) RandomNum(2,1) Global("TCWGWOM42Rihn","TC1000",0)~ THEN BEGIN 5
  SAY ~Ay, now... you looks like a minstrel, you does.  Will you be playin' a tune for us, mayhap?~
  IF ~~ THEN DO ~SetGlobal("TCWGWOM42Rihn","TC1000",1)~ EXTERN ~TCRIHNJ~ Rihn2WestWoman
END


APPEND ~TCRIHNJ~

IF ~~ THEN BEGIN Rihn2WestWoman
  SAY ~Nothing would please me more, good lady... but perhaps another time.~
  IF ~~ THEN EXIT
END
END

APPEND ~TCRILJ~

IF ~~ THEN BEGIN Ril2WestWoman
  SAY ~I would not blame poor weather on the gods.  And were it so, then perhaps the evil throughout this city has earned the gods' displeasure.~
  IF ~~ THEN EXIT
END
END
