BEGIN ~TCSEVDRU~ 2

IF ~!Dead("TCSEVBA1") NumTimesTalkedTo(0)~ THEN BEGIN 0
  SAY ~Hello, hello! Welcome to... ah... what time is it? It's <DAYNIGHTALL>? Then welcome to the <DAYNIGHTALL> showing of the talents of Alateto De Bonito!~
  IF ~~ THEN GOTO 1
END

IF ~~ THEN BEGIN 1
  SAY ~A rousing wave of indifference from the crowd yet again. Ah well, if I let such things bother me I would have given up the stage years ago... ~
  IF ~~ THEN GOTO 2
END

IF ~~ THEN BEGIN 2
  SAY ~...as per the wishes of most of my audience, unfortunately. At least the occasional dwarf applauds. Well, doesn't swear and leave, anyway.~
  IF ~~ THEN GOTO 3
END

IF ~~ THEN BEGIN 3
  SAY ~(hmm... let's see...) A tale of familial woe to tantalize your tears and tempt your time and interest... (ahem)~
  IF ~~ THEN GOTO 4
END

IF ~~ THEN BEGIN 4
  SAY ~" Raised of spells and casting well, but always wanting better, 
To sing of knights and days of yore, to leave the robes that... that fetter!
A wizard prone to song and prose, though oft accused of failing,
I shall sing despite the odds... ~
  IF ~~ THEN EXTERN ~TCSEVBA1~ 18
END

IF ~~ THEN BEGIN 5
  SAY ~Well finished, Missus Patricia, you've a fine ear for rhyme, though... I would hope you'd be more supporting of your own employees...~
  IF ~~ THEN EXTERN ~TCSEVBA1~ 19
END

IF ~~ THEN BEGIN 6
  SAY ~(sigh) Very well, Missus Patricia. Thank you for your indulgence thus far.~
  IF ~~ THEN EXIT
END

IF ~!Dead("TCSEVBA1") NumTimesTalkedTo(1)~ THEN BEGIN 7
  SAY ~I would regale you with songs of daring, my <LADYLORD>, but I fear the room is a touch hostile towards mages that encroach into bardic territory.~
  IF ~Global("TCBardPotion","GLOBAL",0)~ THEN GOTO StartPotionQuest
  IF ~!Global("TCBardPotion","GLOBAL",0)~ THEN EXIT
END

IF ~Dead("TCSEVBA1")~ THEN BEGIN 8
  SAY ~(sigh) With Missus Patricia gone, I imagine reaction to my rhythmic efforts will become ever more violent. Pity the poor mage that would sing with bards.~
  IF ~~ THEN DO ~EscapeArea()~ EXIT
END

IF ~Global("TCBardPotion","GLOBAL",0)~ THEN BEGIN StartPotionQuest
  SAY ~I think my singing talents will be much more appreciated if I have a smooth voice to match. I believe Mistress Fielding may be able to make such a potion but she does not like me very much. Hey, I've got an idea, maybe you can get it for me?~
  IF ~~ THEN REPLY ~Err... Sorry, I'm not about to cross Mistress Fielding.~ GOTO BackoutQuest
  IF ~~ THEN REPLY ~Why can't you get it yourself?~ GOTO WhyShouldI
  IF ~~ THEN REPLY ~What will you give me for my trouble.~ GOTO Reward4Quest
  IF ~~ THEN REPLY ~Sorry, I'm busy right now.~ GOTO DoQuestLater
END

IF ~~ THEN BEGIN BackoutQuest
  SAY ~Come on, she doesn't need to know. You can say it is for yourself.~
  IF ~~ THEN REPLY ~Why can't you get it yourself?~ GOTO WhyShouldI
  IF ~~ THEN REPLY ~What will you give me for my trouble.~ GOTO Reward4Quest
  IF ~~ THEN REPLY ~Sorry, I'm busy right now.~ GOTO DoQuestLater
END

IF ~~ THEN BEGIN WhyShouldI
  SAY ~Well, let's just say I am a better mage than she is, and Mistress Fielding is the jealous sort. So, can you get the potion for me?~
  IF ~~ THEN REPLY ~Err... Sorry, I'm not about to cross Mistress Fielding.~ GOTO BackoutQuest
  IF ~~ THEN REPLY ~What will you give me for my trouble.~ GOTO Reward4Quest
  IF ~~ THEN REPLY ~Sorry, I'm busy right now.~ GOTO DoQuestLater
END

IF ~~ THEN BEGIN Reward4Quest
  SAY ~I have a nice magical necklace here for your troubles.~
  IF ~~ THEN REPLY ~Err... Sorry, I'm not about to cross Mistress Fielding.~ GOTO BackoutQuest
  IF ~~ THEN REPLY ~Why can't you get it yourself?~ GOTO WhyShouldI
  IF ~~ THEN REPLY ~That'll suffice. I'll go get your potion now.~ GOTO DoPotionQuest
  IF ~~ THEN REPLY ~Sorry, I'm busy right now.~ GOTO DoQuestLater
END

IF ~~ THEN BEGIN DoQuestLater
  SAY ~Well, I'm not going anywhere. If you have time later, please get the potion for me.~
  IF ~~ THEN DO ~SetGlobal("TCBardPotion","GLOBAL",1)~ JOURNAL ~Alateto De Bonito wants me to retrieve a potion for him from Mistress Fielding. Supposedly it will make his voice sound better when he tries to sing.~ EXIT
END

IF ~~ THEN BEGIN DoPotionQuest
  SAY ~Thank you. I will be waiting most eagerly.~
  IF ~~ THEN DO ~SetGlobal("TCBardPotion","GLOBAL",1)~ JOURNAL ~Alateto De Bonito wants me to retrieve a potion for him from Mistress Fielding. Supposedly it will make his voice sound better when he tries to sing.~ EXIT
END

IF ~Global("TCBardPotion","GLOBAL",4)~ THEN BEGIN PotionQuestEnd
  SAY ~Do you have the potion yet?~
  IF ~PartyHasItem("TCPOTN03")~ THEN REPLY ~Yes.~ GOTO GetPotion
  IF ~!PartyHasItem("TCPOTN03")~ THEN REPLY ~No.~ GOTO NoPotion
END

IF ~~ THEN BEGIN GetPotion
  SAY ~I'll take that, thank you. Here's your reward.~
  IF ~~ THEN DO ~TakePartyItem("TCPOTN03") GiveItemCreate("TCAMUL01",[PC],1,1,0) SetGlobal("TCBardPotion","GLOBAL",5)~ EXIT
END

IF ~~ THEN BEGIN NoPotion
  SAY ~Well, please get it for me. I'll be waiting most eagerly.~
  IF ~~ THEN EXIT
END

IF ~Global("TCBardPotion","GLOBAL",5)~ THEN BEGIN MakeStuff
  SAY ~Hello there, <GABBER>. What can I help you with?~
  IF ~~ THEN REPLY ~You said that you were a better mage than Mistress Fielding. Can you make anything special?~ GOTO MakeStuff1
  IF ~~ THEN REPLY ~Just stopping by.~ EXIT
END

IF ~~ THEN BEGIN MakeStuff1
  SAY ~Don't like her selection, aye? I don't run a store where I can sell you anything. However, I can make a few special items.~
  IF ~~ THEN REPLY ~Such as?~ GOTO MakeStuff2a
  IF ~PartyHasItem("TCPOTN05")~ THEN REPLY ~Can you make your fire potion even stronger?~ GOTO MakeStuff2b
  IF ~~ THEN REPLY ~Oh, no inventory? Sorry to bother you.~ EXIT
END

IF ~~ THEN BEGIN MakeStuff2a
  SAY ~I can make a more powerful flaming potion than she can. Bring me three oily rags and I will combine them into a jar which can explode like a great fireball.~
  IF ~NumItemsPartyGT("RAGS",2)~ THEN REPLY ~You mean rags like these?~ GOTO MakeStuff3a
  IF ~~ THEN REPLY ~Interesting. I'll see if I can find any.~ EXIT
END

IF ~~ THEN BEGIN MakeStuff3a
  SAY ~Yes, those are perfect. I need three rags and it will cost you 600 gold to make the potion. Are you interested?~
  IF ~PartyGoldGT(599)~ THEN REPLY ~Yes, make me a potion.~ DO ~TakePartyGold(600) Destroygold(600) TakePartyItemNum("RAGS",3) DestroyItem("RAGS") GiveItemCreate("TCPOTN05",LastTalkedToBy(Myself),1,0,0)~ GOTO MakeStuff4
  IF ~~ THEN REPLY ~Not right now.~ EXIT
END

IF ~~ THEN BEGIN MakeStuff2b
  SAY ~It would be very dangerous, but yes, I can make an even more powerful flaming potion. Bring me two of my fire potions and I will combine them into a jar which can explode into a bigger fireball. And, as a treat to you, it will only hurt your enemies, not you or your friends.~
  IF ~NumItemsPartyGT("TCPOTN05",1)~ THEN REPLY ~Sounds good. Can you make it now?~ GOTO MakeStuff3b
  IF ~~ THEN REPLY ~I'll have to think about this.~ EXIT
END

IF ~~ THEN BEGIN MakeStuff3b
  SAY ~Yes. I need two potions and it will cost you 600 gold to make the stronger potion. Are you interested?~
  IF ~PartyGoldGT(599)~ THEN REPLY ~Yes, make me a potion.~ DO ~TakePartyGold(600) Destroygold(600) TakePartyItemNum("TCPOTN05",2) DestroyItem("TCPOTN05") GiveItemCreate("TCPOTN06",LastTalkedToBy(Myself),1,0,0)~ GOTO MakeStuff4
  IF ~~ THEN REPLY ~Not right now.~ EXIT
END

IF ~~ THEN BEGIN MakeStuff4
  SAY ~There you go. A pleasure doing business with you.~
  IF ~~ THEN EXIT
END
