BEGIN ~TCWGRUF2~ 2

IF WEIGHT #4 ~RandomNum(4,1)~ THEN BEGIN 0
  SAY ~Har, get ye well enough away, or ye'll feel my axe, ye will!~
  IF ~~ THEN EXIT
END

IF WEIGHT #5 ~RandomNum(4,2)~ THEN BEGIN 1
  SAY ~I be thinkin' that it were the fish that smelled so... now I sees it be only ye.~
  IF ~~ THEN EXIT
END

IF WEIGHT #6 ~RandomNum(4,3)~ THEN BEGIN 2
  SAY ~Care to be tryin' yer strength out against a dwarf, aye?  I bet I could be takin' ye but easy.~
  IF ~~ THEN EXIT
END

IF WEIGHT #7 ~RandomNum(4,4)~ THEN BEGIN 3
  SAY ~Ye should be more careful... ye walk around with yer mouth open like a bleedin' tourist.  In this part o' town, that be nothing but an invitation, aye?~
  IF ~~ THEN EXIT
END

IF WEIGHT #0 ~IsValidForPartyDialog("TCRURIK") RandomNum(2,1) Global("TCWGRUF2Rurik","TC1000",0)~ THEN BEGIN 4
  SAY ~Ha!  I be thinkin' I never seen more sorry a lot than ye!~
  IF ~~ THEN DO ~SetGlobal("TCWGRUF2Rurik","TC1000",1)~ EXTERN ~TCRURIKJ~ RurikRuffian
END

IF ~~ THEN BEGIN 5
  SAY ~Oh... er... aye, my regrets.~
  IF ~~ THEN EXIT
END

IF WEIGHT #1 ~IsValidForPartyDialog("TCSHADOW") RandomNum(2,2) Global("TCWGRUF2Shadow","TC1000",0)~ THEN BEGIN 6
  SAY ~Oh, I likes 'em short, I does.  Look at the lil' sweet one thar!~
  IF ~~ THEN DO ~SetGlobal("TCWGRUF2Shadow","TC1000",0)~ EXTERN ~TCSHADOJ~ ShadowRuffian
END

IF WEIGHT #2 ~IsValidForPartyDialog("TCERKY") RandomNum(2,2) Global("TCWGRUF2Erky","TC1000",0)~ THEN BEGIN 7
  SAY ~Hah!  I bet ye'll all be robbed an' sent bleedin' an' screamin' from the Docks within the hour, sure enough!~
  IF ~~ THEN DO ~SetGlobal("TCWGRUF2Erky","TC1000",1)~ EXTERN ~TCERKYJ~ ErkyRuffian
END

IF WEIGHT #3 ~IsValidForPartyDialog("TCBLOD") RandomNum(2,2) Global("TCWGRUF2Blodget","TC1000",0)~ THEN BEGIN 8
  SAY ~Ha!  Look at the strange-faced one, there!  'Tis a demon, sure as sure is sure!  A demon!~
  IF ~~ THEN DO ~SetGlobal("TCWGRUF2Blodget","TC1000",1)~ EXTERN ~TCBLODJ~ BlodgetRuffian
END


APPEND ~TCBLODJ~

IF ~~ THEN BEGIN BlodgetRuffian
  SAY ~Oy, 'ere now, you don't see me talkin' 'bout your goblin beddin' mum now do ya?~
  IF ~~ THEN EXIT
END
END

APPEND ~TCERKYJ~

IF ~~ THEN BEGIN ErkyRuffian
  SAY ~Shouldn't you be digging out tunnels with your face?~
  IF ~~ THEN EXIT
END
END

APPEND ~TCRURIKJ~

IF ~~ THEN BEGIN RurikRuffian
  SAY ~I would be watching who ye be calling sorry... I, myself, have ne'er seen a sorrier excuse fer a comrade in harm than yerself, orc dung.~
  IF ~~ THEN EXTERN ~TCWGRUF2~ 5
END
END

APPEND ~TCSHADOJ~

IF ~~ THEN BEGIN ShadowRuffian
  SAY ~Is that the best ya got?  I'm from the Keep and we don't make comments we can't backup ya bearded gnome.~
  IF ~~ THEN EXIT
END
END
